doomclaw.de

What?

This is a guide on how to install Windows 7 using a syslinux-based PXE server.

Why?

Since I got a ThinkPad X61 Tablet and no X6 Tablet Ultrabase or any other external DVD drive I have to install every operating system on this laptop with USB flash drives or, and this is the prettier way, over my home network. To accomplish this I’ve set up a PXE server for all the Linuxes I use. But I still had to use CD’s and DVD’s for installing Windows.

There are some ways to install Windows XP through PXE but the problem with these solutions is that you will need a Windows Server machine for this. You could also use a Linux machine with a PXE server running and boot into a memdisk with the installation disc image loaded. But the PXE booted memdisk will only take up to 500MB of data and every (not modified) XP image is larger than this.

With the release of Windows Vista Microsoft released a new version of their Preinstallation Environment which is said to work better on Linux PXE servers. There are some howtos about this on the net but I never tried this.

Now with the upcoming release of Windows 7 there will be another new version of Windows PE. This guide will show how to accomplish the task of using Windows PE 3.0 with a syslinux-based PXE environment.

What will you need?

• A working PXE boot server with syslinux (there are plenty of howtos, just google them). If you plan to use a Linux server as I did, I would recommend to use tftpd-hpa because it supports path remappings. Without these remappings the TFTP server won’t find the correct paths in your filesystem, because some paths are hardcoded.
• An image of your Windows 7 Installation disc (I’ve just used the images I downloaded from MSDN)
• The Windows Automated Installation Kit (AIK) for Windows 7 (Download)
• A working Windows-based computer (I have used an installation of Windows XP in VirtualBox)

How?

1. Run the Windows AIK Setup on your Windows computer.
2. Start the Deployment tools command prompt.
3. Run the following shell script. It will prepare your Windows bootloader for usage with PXE. There are some variables set in the lines 5-17. You can change them to your favor.

   @echo off
   cls
   
   REM Variables
   echo Setting variables ...
   REM the path to your WAIK installation
   set WAIKPath=%ProgramFiles%\Windows AIK
   echo Set WAIK directory to %WAIKPath%.
   REM possible values are: x86, amd64 and ia64
   set ARCH=x86
   echo Set architecture to %ARCH%.
   set PEPath=C:\winpe_%ARCH%
   echo Set temporary working directory for Windows PE to %PEPath%.
   set TFTPPath=C:\tftp\Boot
   echo Set TFTP boot directory to %TFTPPath%.
   REM Don't change this one!
   set BCDStore=%TFTPPath%\BCD
   echo Set BCD store to %BCDStore%.
   echo All variables set!
   echo.
   
   REM Environment check
   echo Checking for clean environment...
   if not exist "%WAIKPATH%" set NoWAIK=1 && goto :end
   if not exist "%WAIKPath%\Tools\PETools\%ARCH%" set NoARCH=1 && goto :end
   if exist %PEPath% echo Temporary working directory not empty! Need to remove && rd %PEPath% /S
   if exist %PEPath% echo Temporary working directory still not empty! Trying again ... && cd "%WAIKPath%\Tools\%ARCH%" && imagex /unmount %PEPath%\mount && rd %PEPath% /S /Q
   if exist %PEPath% set NotClean=1 && goto :end
   if exist %TFTPPath% echo TFTP boot directory not empty! Need to remove && rd %TFTPPath% /S
   if exist %TFTPPath% set NotClean=1 && goto :end
   if exist %BCDStore% echo BCD store existing! Need to remove && del /P %BCDStore%
   if exist %BCDStore% set NotClean=1 && goto :end
   echo.
   
   REM WORK!
   echo Starting real work now ...
   cd "%WAIKPath%\Tools\PETools"
   echo Copying PE-Files ...
   call copype %ARCH% %PEPath%
   echo Mounting Windows PE image ...
   imagex /mountrw %PEPath%\winpe.wim 1 %PEPath%\mount
   md %TFTPPath% > NUL
   copy %PEPath%\mount\Windows\Boot\PXE\*.* %TFTPPath% > NUL
   copy "%WAIKPath%\Tools\PETools\%ARCH%\boot\boot.sdi" %TFTPPath% > NUL
   copy %PEPath%\winpe.wim %TFTPPath% > NUL
   cd %PEPath%\mount\Windows\System32
   bcdedit -createstore %BCDStore%
   bcdedit -store %BCDStore% -create {ramdiskoptions} /d "Ramdisk options"
   bcdedit -store %BCDStore% -set {ramdiskoptions} ramdisksdidevice  Boot
   bcdedit -store %BCDStore% -set {ramdiskoptions} ramdisksdipath  \Boot\boot.sdi
   for /f "Tokens=3" %%i in ('bcdedit /store %BCDStore% /create /d "Windows 7 Install Image" /application osloader') do set GUID=%%i
   bcdedit -store %BCDStore% -set %GUID% systemroot \Windows
   bcdedit -store %BCDStore% -set %GUID% detecthal Yes
   bcdedit -store %BCDStore% -set %GUID% winpe Yes
   bcdedit -store %BCDStore% -set %GUID% osdevice ramdisk=[boot]\Boot\boot.wim,{ramdiskoptions}
   bcdedit -store %BCDStore% -set %GUID% device ramdisk=[boot]\Boot\boot.wim,{ramdiskoptions}
   bcdedit -store %BCDStore% -create {bootmgr} /d "Windows 7 Boot Manager"
   bcdedit -store %BCDStore% -set {bootmgr} timeout 30
   bcdedit -store %BCDStore% -set {bootmgr} displayorder %GUID%
   bcdedit -store %BCDStore%
   pause
   goto :exit
   
   :end
   if %NoWAIK%=1 echo "Your WAIK directory was not found. Execution aborted." && pause && goto :exit
   if %NoARCH%=1 echo "Your Architecture doesn't seem to be right. Or at least it is not known by your WAIK installation. Execution aborted." && pause && goto :exit
   if %NotClean%=1 echo "Your environment was not clean. Execution aborted." && pause && goto :exit
   
   :exit

4. If nothing went wrong you should have some files in the directory which is set in the TFTPPath variable. Copy these files into a subdirectory of your TFTP servers boot directory. In my case this is /var/lib/tftpboot.
   If you’re not using tftpd-hpa you should place all files into a subdirectory called “Boot”. This is very essential.
   If you’re using tftpd-hpa you can place it in any subdirectory you want to, because you can remap the paths. I chose /var/lib/tftpboot/windows/7.For the remapping we need to do some extra steps:
   1. Create a remapping file called /var/lib/tftpdboot/tftpd.remap with the following content (change paths to your needs):

      re ^pxeboot\.n12 windows/7/pxeboot.n12
      re ^pxeboot\.com windows/7/pxeboot.com
      re ^pxeboot\.0 windows/7/pxeboot.n12
      re ^bootmgr\.exe windows/7/bootmgr.exe
      r ^\\Boot\\ windows/7/
      r ^\\boot\\ windows/7/
      r ^Boot/ windows/7/
      r ^/Boot/ windows/7/
      r ^boot/ windows/7/
      r ^/boot/ windows/7/
      r ^\\ windows/7/
      rg \\ /

   2. Edit your tftpd-hpa configuration in /etc/default/tftpd-hpa to parse the remappings:

      #Defaults for tftpd-hpa
      RUN_DAEMON="yes"
      OPTIONS="-l -m /var/lib/tftpboot/tftpd.remap -s /var/lib/tftpboot -vvv"

      The -vvv part is optional, but highy recommended to get the most verbose output in /var/log/syslog.

5. Now you’ll need to create some symbolic links in your Windows boot directory.

   ln -s pxeboot.n12 startrom.0
   ln -s winpe.wim boot.wim

6. To map the Image in your pxelinux menu just edit your pxelinux config and add the following lines:

   LABEL win7
           MENU LABEL Windows 7
           KERNEL Boot/startrom.0

7. Because the boot image is just a Windows PE image with a minimal shell you’ll need to make your installation source accessible over your network. For this I’ve just created a guest-readable samba share on the same server where my PXE server resides.
   You’ll need to copy the content of the sources directory on your installation media into this share.
8. The configuration is done. Let’s try to install Windows 7. Start your target computer, boot into your PXE menu and choose the Windows 7 menu point. When the system is completely booted you should get the mentioned Windows shell. To connect to your installation share and start the stup just type the following commands (where the text in squared brackets should be replaced with the appropriate data):

   net use y: \\[IP of your share server]\[name of your share]
   y:
   setup.exe

That’s all the installation of windows 7 should start now.

Additional notes:

• It is not possible to run a x86 Windows PE and start an amd64 installation from this. If you plan to install an amd64 System but only got an x86 system to do the configuration (or vice versa) you might run into errors. In this case just configure the installation source for the architecture you’re currently using. At the end you can just copy the winpe.wim you would like to use from %ProgramFiles%\Windows AIK\Tools\PETools\%ARCH% into your source and overwrite the old one.
  You can also place both files in your source directory and just change the symlink to the right file. This is the way I did it. The last option is to create a second entry in the PE boot loader with bcdedit. But this caused my boot loader to have two entries, both named “Ramdisk options” but pointing to different images (x86 and amd64). This could be confusing if you don’t remember which entry entry is for x86 or amd64.
• If you plan to use a Windows based PXE server for the installation I recommend tftpd32. I have not tried this way but the most how-to’s for installing Windows Vista by PXE recommend this one. You need to set pxeboot.com as boot file, you can skip the steps 5 and 6 and you’ll have to rename the winpe.wim to boot.wim.
• Maybe it’s possible to load the Installation image of Windows 7 directly. It’s located in the sources directory of your installation media and is named install.wim. But you’ll definitely need much RAM for this, because both images, x86 and amd64, are over 2GB in size. I was not able to try this because my laptop only got 2GB RAM, so the boot loader blocked loading of an image of this size. But I’m not sure if the error message derived from my amount of RAM or if there was another error while using this image.
• This guide should work for Windows Vista as well or at least the steps should be very similar.

Thanks to…

• Joshua Flanagan for his excelent guides [1] [2] to accomplish this with Windows Vista and tftpd32.
• Gernot Stöckl for some ideas I derived from his Wiki.

Any comments, additions and corrections are greatly appreciated.